Option Explicit

Dim WSHShell
Dim rc, sw, key
Dim RegKeyMA(4), RegKeyVSE(12)
Dim AgentInstPath, AgentUninstCmd, VseUninstCmd
Dim MsgStr


'
rc = 0
sw = 0
AgentInstPath = ""
AgentUninstCmd = ""
VseUninstCmd = ""
MsgStr = ""

RegKeyMA(0) = "HKLM\SOFTWARE\McAfee\ePolicy Orchestrator\Agent\Installed Path"
RegKeyMA(1) = "HKLM\SOFTWARE\Network Associates\ePolicy Orchestrator\Agent\Installed Path"
RegKeyMA(2) = "HKLM\SOFTWARE\Wow6432Node\McAfee\ePolicy Orchestrator\Agent\Installed Path"
RegKeyMA(3) = "HKLM\SOFTWARE\Wow6432Node\Network Associates\ePolicy Orchestrator\Agent\Installed Path"

RegKeyVSE(0) = "HKLM\SOFTWARE\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8600\Uninstall Command"
RegKeyVSE(1) = "HKLM\SOFTWARE\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8700\Uninstall Command"
RegKeyVSE(2) = "HKLM\SOFTWARE\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8800\Uninstall Command"
RegKeyVSE(3) = "HKLM\SOFTWARE\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8600\Uninstall Command"
RegKeyVSE(4) = "HKLM\SOFTWARE\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8700\Uninstall Command"
RegKeyVSE(5) = "HKLM\SOFTWARE\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8800\Uninstall Command"
RegKeyVSE(6) = "HKLM\SOFTWARE\Wow6432Node\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8600\Uninstall Command"
RegKeyVSE(7) = "HKLM\SOFTWARE\Wow6432Node\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8700\Uninstall Command"
RegKeyVSE(8) = "HKLM\SOFTWARE\Wow6432Node\McAfee\ePolicy Orchestrator\Application Plugins\VIRUSCAN8800\Uninstall Command"
RegKeyVSE(9) = "HKLM\SOFTWARE\Wow6432Node\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8600\Uninstall Command"
RegKeyVSE(10) = "HKLM\SOFTWARE\Wow6432Node\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8700\Uninstall Command"
RegKeyVSE(11) = "HKLM\SOFTWARE\Wow6432Node\Network Associates\ePolicy Orchestrator\Application Plugins\VIRUSCAN8800\Uninstall Command"

' for Windows Vista/7 UAC
Dim objWMI, objShell, osInfo, os 
Do while WScript.Arguments.Count = 0 and WScript.Version >= 5.7
	Set objWMI = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")
	Set osInfo = objWMI.ExecQuery("SELECT * FROM Win32_OperatingSystem")
	
	For Each os in osInfo
		If left(os.Version, 3) < 6.0 Then exit do
	Next
	
	Set objShell=CreateObject("Shell.Application")  
	objShell.ShellExecute "wscript.exe", Chr(34) & WScript.ScriptFullName & Chr(34) & " uac","","runas",1
	WScript.Quit
Loop


'
On Error Resume Next
Set WSHShell = WScript.CreateObject("WScript.Shell")

'for Agent
For Each key in RegKeyMA
	AgentInstPath = WSHShell.RegRead(key)
	if Err.Number = 0 Then
		AgentUninstCmd = Chr(34) & AgentInstPath & "\FrmInst.exe" & Chr(34) & " /remove=agent"
		sw = sw + 1
		Exit For
	End If
	Err.Clear
Next
'for VSE
For Each key in RegKeyVSE
	VseUninstCmd = WSHShell.RegRead(key)
	if Err.Number = 0 Then
		VseUninstCmd = VseUninstCmd & "b"
		sw = sw + 2
		Exit For
	End If
	Err.Clear
Next


Select Case sw
	Case 1
		MsgStr = "　・ McAfee Common Framework"
	Case 2
		MsgStr = "　・ McAfee VirusScan Enterprise"
	Case 3
		MsgStr = "　・ McAfee Common Framework" & VbCrLf _
			& "　・ McAfee VirusScan Enterprise"
	Case Else
		MsgStr = "アンインストール対象のソフトウェアが見つかりません。" _
			& "アンインストールを続行することができません。"
End Select


If sw >= 1 And sw <= 3 Then
	MsgStr = "次のソフトウェアのアンインストールを行います。" _
		& VbCrLf & MsgStr & VbCrLf & VbCrLf _
		& "アンインストールには数分程度の時間がかかります。"
	rc = MsgBox(MsgStr, vbOKCancel, "ウィルス対策ソフト アンインストーラー")
	If rc = vbOK Then
		
		MsgStr = "アンインストールが完了しました。"
		
		If sw = 2 Or sw = 3 Then
			WSHShell.Run VseUninstCmd, 1, True
			If Err.Number <> 0 Then
				Err.clear
				MsgStr = "アンインストール中にエラーが発生しました。" _
					& "コンピュータを再起動し、再度実行してください。" _
					& "このエラーが続く場合はネットワーク管理課までお問い合わせください。"
			End If
		End If

		If sw = 1 Or sw = 3 Then
			WSHShell.Run AgentUninstCmd, 1, True
			
			If Err.Number <> 0 Then
				Err.clear
				MsgStr = "アンインストール中にエラーが発生しました。" _
					& "コンピュータを再起動後再度実行してください。" _
					& "このエラーが続く場合はネットワーク管理課までお問い合わせください。"
			End If
		End If

		
	Else
		MsgStr = "アンインストールがキャンセルされました。"
	End If
End If

rc = MsgBox(MsgStr, vbOKonly, "ウィルス対策ソフト アンインストーラー")